Attachment 297905 Details for Bug 243986 – Syscall usage stap script

Syscall usage stap script

syscall-usage.stp (text/plain), 1.00 KB, created by Matthew Booth on 2008-03-13 09:49:29 UTC

(hide)

Description:

Filename:

MIME Type:

Creator: Matthew Booth

Created: 2008-03-13 09:49:29 UTC

Size: 1.00 KB

patch

obsolete

># timers stores system call entry time indexed by thread id
>global timers
>
># syscalls stores total time spent in system call indexed by <app>.<syscall>
>global syscalls
>
># Called on entry to every system call
>probe syscall.* {
>    exe = execname();
>
>    # Only monitor target processes
>    if(exe != "logger" &&
>       exe != "syslogd" &&
>       exe != "seq") next;
>
>    timers[tid()] = gettimeofday_ms();
>}
>
># Called on return of every system call
>probe syscall.*.return {
>    tid = tid();
>
>    # If we didn't catch the entry, ignore the exit
>    if(!([tid] in timers)) next;
>
>    # Record the total amount of time spent in this system call
>    duration = gettimeofday_ms() - timers[tid];
>
>    if(duration > 0) {
>        syscalls[execname().".".probefunc()] <<< duration;
>    }
>
>    # Delete the system call entry time
>    delete timers[tid];
>}
>
># Called when the script exits
>probe end {
>    # Display the totals from syscalls
>    foreach (call in syscalls) {
>        printf("%s %i\n", call, @sum(syscalls[call]));
>    }
>}

Actions: View

Attachments on bug 243986: 297905