Attachment 637288 Details for Bug 709351 – deduplicating df proof of concept (in Perl)

deduplicating df proof of concept (in Perl)

df.pl (text/plain), 1.28 KB, created by Michal Schmidt on 2012-11-02 21:33:36 UTC

(hide)

Description:

Filename:

MIME Type:

Creator: Michal Schmidt

Created: 2012-11-02 21:33:36 UTC

Size: 1.28 KB

patch

obsolete

>#!/usr/bin/perl -w
>use strict;
>use warnings;
>use Filesys::Df;
>
>my @table;        # array of mount entries
>my %preferred;    # "major:minor" -> mount entry
>
>open(MI, "</proc/self/mountinfo") or die;
>while (<MI>) {
>	/^(\d+) (\d+) (\d+):(\d+) (\S+) (\S+) (\S+) ([^-]*)- (\S+) (\S+) (\S+)/ or die;
>	my %entry = (
>		id => $1,
>		parent => $2,
>		major => $3,
>		minor => $4,
>		root => $5,
>		mntpoint => $6,
>		mntopts => $7,
>		fields => $8,
>		type => $9,
>		source => $10,
>		sbopts => $11
>	);
>
>	next if $entry{type} eq "autofs";
>
>	# Store entry
>	push(@table, \%entry);
>
>	# Have one preferred entry per block device. If this b.d. already has
>	# an entry linked, prefer the entry with the shorter root path.
>	my $key = "$entry{major}:$entry{minor}";
>	if (not defined $preferred{$key} or
>	    length(${$preferred{$key}}{root}) > length($entry{root})) {
>		$preferred{$key} = \%entry;
>	}
>}
>
>printf("%-30s %9s %9s %9s %3s%% %s\n",
>       "Filesystem", "1K-blocks", "Used", "Available", "Use", "Mounted on");
>foreach my $ent(@table) {
>
>	# Skip bind mounts
>	my $key = "$$ent{major}:$$ent{minor}";
>	next if $ent != $preferred{$key};
>
>	my $df = df($$ent{mntpoint});
>	next if not defined $df;
>
>	printf("%-30s %9d %9d %9d %3d%% %s\n",
>	       ${$ent}{source}, $$df{blocks}, $$df{used}, $$df{bavail}, $$df{per}, $$ent{mntpoint});
>}

Actions: View

Attachments on bug 709351: 637288