Attachment 654929 Details for Bug 877095 – unclosed-fds.stp

unclosed-fds.stp

unclosed-fds.stp (text/plain), 1.00 KB, created by Jiri Denemark on 2012-11-30 10:57:18 UTC

(hide)

Description:

Filename:

MIME Type:

Creator: Jiri Denemark

Created: 2012-11-30 10:57:18 UTC

Size: 1.00 KB

patch

obsolete

>#!/usr/bin/stap
>
>/*
> * Usage: stap -d process_binarry --ldd unclosed-fds.stp process_name
> *
> */
>
>global fds, bt
>
>probe begin
>{
>    printf("Tracking unclosed fds...\n");
>}
>
>function get_backtrace:string()
>{
>    return str_replace(sprint_ubacktrace(), "\n", "\n  ")
>}
>
>probe end
>{
>    printf("\nUnclosed fds:\n");
>    foreach ([pid, fd] in fds) {
>        printf("%d: \"%s\" still open as %d from:\n  %s\n",
>               pid, fds[pid, fd], fd, bt[pid, fd])
>    }
>}
>
>probe syscall.open.return
>{
>    if ($return >= 0 && execname() == @1) {
>        fds[pid(), $return] = user_string($filename)
>        bt[pid(), $return] = get_backtrace()
>        printf("%d(%s): open(\"%s\") = %d\n  %s\n",
>               pid(), execname(), user_string($filename), $return,
>               bt[pid(), $return])
>    }
>}
>
>probe syscall.close
>{
>    if ([pid(), $fd] in fds) {
>        printf("%d(%s): fd %d closed\n  %s\n",
>               pid(), execname(), $fd, get_backtrace())
>        delete fds[pid(), $fd]
>        delete bt[pid(), $fd]
>    }
>}

Actions: View

Attachments on bug 877095: 654929 | 655169