Attachment 866998 Details for Bug 1069257 – cmake patch

[patch] cmake patch

fparser.cmake.patch (text/plain), 42.26 KB, created by Till Hofmann on 2014-02-24 15:28:05 UTC

(hide)

Description:

Filename:

MIME Type:

Creator: Till Hofmann

Created: 2014-02-24 15:28:05 UTC

Size: 42.26 KB

patch

obsolete

>diff -urN fparser.orig/CMakeLists.txt fparser/CMakeLists.txt
>--- fparser.orig/CMakeLists.txt	1970-01-01 01:00:00.000000000 +0100
>+++ fparser/CMakeLists.txt	2014-02-24 15:45:44.743197071 +0100
>@@ -0,0 +1,195 @@
>+cmake_minimum_required (VERSION 2.6.0)
>+project (fparser)
>+set( CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS TRUE )
>+
>+# Define here the needed parameters
>+set(FPARSER_VERSION_MAJOR 4)
>+set(FPARSER_VERSION_MINOR 5)
>+set(FPARSER_VERSION_PATCH 1)
>+set(FPARSER_VERSION ${FPARSER_VERSION_MAJOR}.${FPARSER_VERSION_MINOR}.${FPARSER_VERSION_PATCH})
>+set(FPARSER_SOVERSION ${FPARSER_VERSION_MAJOR}.${FPARSER_VERSION_MINOR}.${FPARSER_VERSION_PATCH})
>+set(FPARSER_INCLUDE_INSTALL_DIR "include")
>+
>+message(STATUS "Compiling fparser version ${FPARSER_VERSION}")
>+message(STATUS "Using cmake version ${CMAKE_MAJOR_VERSION}.${CMAKE_MINOR_VERSION}" )
>+
>+option(OPT_BUILD_PACKAGES "Set to ON to generate CPack configuration files and packaging targets" OFF)
>+set(PACKAGE_VERSION "0" CACHE STRING "the package-specific version used for uploading the sources")
>+
>+# http://www.cmake.org/cmake/help/cmake-2.6.html#policy:CMP0002
>+cmake_policy(SET CMP0002 NEW)
>+# http://www.cmake.org/cmake/help/cmake-2.6.html#policy:CMP0003
>+cmake_policy(SET CMP0003 NEW)
>+# http://www.cmake.org/cmake/help/cmake-2.6.html#policy:CMP0005
>+cmake_policy(SET CMP0005 NEW)
>+
>+# Use, i.e. don't skip the full RPATH for the build tree
>+set(CMAKE_SKIP_BUILD_RPATH  FALSE)
>+
>+# When building, don't use the install RPATH already
>+# (but later on when installing)
>+set(CMAKE_BUILD_WITH_INSTALL_RPATH FALSE)
>+
>+# The RPATH to be used when installing
>+set(CMAKE_INSTALL_RPATH "${CMAKE_INSTALL_PREFIX}/lib${LIB_SUFFIX}")
>+
>+# Add the automatically determined parts of the RPATH
>+# which point to directories outside the build tree to the install RPATH
>+set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
>+set(CMAKE_MODULE_PATH "${CMAKE_CURRENT_SOURCE_DIR}/modules-cmake")
>+
>+message(STATUS "installing to ${CMAKE_INSTALL_PREFIX}")
>+
>+include(CheckIncludeFile)
>+include(CheckIncludeFileCXX)
>+include(CheckFunctionExists)
>+include(CheckLibraryExists)
>+include(CheckTypeSize)
>+
>+check_type_size("float" HAVE_FLOAT_SIZE BUILTIN_TYPES_ONLY)
>+if( HAVE_FLOAT_SIZE EQUAL 4 )
>+  set(FP_SUPPORT_FLOAT_TYPE 1 CACHE STRING "support float type")
>+endif()
>+
>+check_type_size("long int" HAVE_LONG_INT_SIZE BUILTIN_TYPES_ONLY)
>+if( HAVE_LONG_INT_SIZE EQUAL 8 )
>+  set(FP_SUPPORT_LONG_INT_TYPE 1 CACHE STRING "support long int type")
>+endif()
>+
>+if( CMAKE_COMPILER_IS_GNUCC OR CMAKE_COMPILER_IS_GNUCXX )
>+  set(CMAKE_REQUIRED_LIBRARIES m)
>+endif()
>+
>+# check if alloca exists
>+check_include_file(alloca.h HAVE_ALLOCA_H)
>+set(FP_USE_THREAD_SAFE_EVAL 1 CACHE STRING "use thread-safety")
>+if( HAVE_ALLOCA_H )
>+  set(FP_USE_THREAD_SAFE_EVAL_WITH_ALLOCA 1 CACHE STRING "use thread-safety with alloca")
>+endif()
>+
>+set(FP_SUPPORT_OPTIMIZER 1 CACHE STRING "support optimized computations")
>+set(FP_SUPPORT_COMPLEX_DOUBLE_TYPE 1 CACHE STRING "support complex double types")
>+set(FP_SUPPORT_COMPLEX_FLOAT_TYPE 1 CACHE STRING "support complex float types")
>+
>+check_function_exists(strtof FP_USE_STRTOF)
>+check_function_exists(strtold FP_USE_STRTOLD)
>+check_type_size("long double" HAVE_LONG_DOUBLE_SIZE BUILTIN_TYPES_ONLY)
>+if( HAVE_LONG_DOUBLE_SIZE EQUAL 16 )
>+  set(FP_SUPPORT_LONG_DOUBLE_TYPE 1 CACHE STRING "support long double")
>+endif()
>+if( HAVE_LONG_DOUBLE_SIZE EQUAL 16 )
>+  set(FP_SUPPORT_COMPLEX_LONG_DOUBLE_TYPE 1 CACHE STRING "support complex long double")
>+endif()
>+
>+#should be faster at a cost
>+set(FP_NO_EVALUATION_CHECKS 0 CACHE STRING "no evaluation checks")
>+
>+set(fparser_SOURCES fparser.cc ) # fpoptimizer.cc
>+
>+# math libraries
>+find_package(GMP)
>+find_package(GMPXX)
>+find_package(MPFR 2.4)
>+if( MPFR_FOUND )
>+  check_library_exists(${MPFR_LIBRARIES} mpfr_div_d "${MPFR_LIBRARIES_DIR}" MPFR_DIV_D_FOUND)
>+  if( NOT MPFR_DIV_D_FOUND )
>+    message(WARNING "MPFR verison too old, does not support mpfr_div_d function")
>+    set(MPFR_FOUND 0)
>+  endif()
>+endif()
>+find_package(MPFI)
>+
>+set(fparser_LIBRARIES)
>+set(fparser_LIBRARIES_DIR)
>+
>+set(FP_SUPPORT_MPFR_FLOAT_TYPE ${MPFR_FOUND} CACHE STRING "use mpfr float")
>+if( FP_SUPPORT_MPFR_FLOAT_TYPE )
>+  set(fparser_SOURCES ${fparser_SOURCES} mpfr/MpfrFloat.cc)
>+  set(fparser_LIBRARIES ${fparser_LIBRARIES} ${MPFR_LIBRARIES})
>+  set(fparser_LIBRARIES_DIR ${fparser_LIBRARIES_DIR} ${MPFR_LIBRARIES_DIR})
>+  install(FILES fparser_mpfr.hh DESTINATION ${FPARSER_INCLUDE_INSTALL_DIR}/fparser COMPONENT fparser-dev)
>+  install(FILES mpfr/MpfrFloat.hh  DESTINATION ${FPARSER_INCLUDE_INSTALL_DIR}/fparser/mpfr COMPONENT fparser-dev)
>+endif()
>+
>+set(FP_SUPPORT_GMP_INT_TYPE ${GMP_FOUND} CACHE STRING "use gmp int")
>+if( FP_SUPPORT_GMP_INT_TYPE )
>+  set(fparser_SOURCES ${fparser_SOURCES} mpfr/GmpInt.cc)
>+  set(fparser_LIBRARIES ${fparser_LIBRARIES} ${GMP_LIBRARIES})
>+  set(fparser_LIBRARIES_DIR ${fparser_LIBRARIES_DIR} ${GMP_LIBRARIES_DIR})
>+  install(FILES fparser_gmpint.hh DESTINATION ${FPARSER_INCLUDE_INSTALL_DIR}/fparser COMPONENT fparser-dev)
>+  install(FILES mpfr/GmpInt.hh DESTINATION ${FPARSER_INCLUDE_INSTALL_DIR}/fparser/mpfr COMPONENT fparser-dev)
>+endif()
>+
>+configure_file(${CMAKE_CURRENT_SOURCE_DIR}/fpconfig.hh.in ${CMAKE_CURRENT_SOURCE_DIR}/fpconfig.hh)
>+
>+include_directories(${CMAKE_CURRENT_SOURCE_DIR})
>+link_directories(${fparser_LIBRARIES_DIR})
>+add_library(fparser SHARED ${fparser_SOURCES})
>+set_target_properties(fparser PROPERTIES
>+  COMPILE_FLAGS "${EXTRA_COMPILE_FLAGS}"
>+  SOVERSION ${FPARSER_SOVERSION}
>+  VERSION ${FPARSER_VERSION}
>+  OUTPUT_NAME fparser${FPARSER_SOVERSION}
>+  CLEAN_DIRECT_OUTPUT 1)
>+target_link_libraries(fparser ${fparser_LIBRARIES})
>+
>+if( MSVC )
>+  install(TARGETS libfparser RUNTIME DESTINATION bin COMPONENT libfparser LIBRARY DESTINATION bin COMPONENT libfparser ARCHIVE DESTINATION lib${LIB_SUFFIX} COMPONENT libfparser${FPARSER_SOVERSION})
>+else()
>+  install(TARGETS fparser DESTINATION lib${LIB_SUFFIX} COMPONENT libfparser${FPARSER_SOVERSION})
>+endif()
>+
>+install(FILES fparser.hh fpconfig.hh extrasrc/fpaux.hh extrasrc/fptypes.hh DESTINATION ${FPARSER_INCLUDE_INSTALL_DIR}/fparser COMPONENT fparser-dev)
>+
>+configure_file("${CMAKE_CURRENT_SOURCE_DIR}/fparser-config.cmake.in" "${CMAKE_CURRENT_BINARY_DIR}/fparser-config.cmake" @ONLY IMMEDIATE)
>+configure_file("${CMAKE_CURRENT_SOURCE_DIR}/fparser-config-version.cmake.in" "${CMAKE_CURRENT_BINARY_DIR}/fparser-config-version.cmake" @ONLY IMMEDIATE)
>+install(FILES "${CMAKE_CURRENT_BINARY_DIR}/fparser-config.cmake" "${CMAKE_CURRENT_BINARY_DIR}/fparser-config-version.cmake" DESTINATION "lib${LIB_SUFFIX}/cmake/fparser-${FPARSER_SOVERSION}" COMPONENT fparser-dev)
>+
>+# add make uninstall capability
>+configure_file("${CMAKE_CURRENT_SOURCE_DIR}/modules-cmake/cmake_uninstall.cmake.in" "${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake" IMMEDIATE @ONLY)
>+add_custom_target(uninstall "${CMAKE_COMMAND}" -P "${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake")
>+
>+if(CMAKE_CPACK_COMMAND AND UNIX AND OPT_BUILD_PACKAGES)
>+  # Packing information
>+  set(CPACK_PACKAGE_NAME fparser)
>+  set(CPACK_PACKAGE_CONTACT "" CACHE STRING "Package maintainer and PGP signer.")
>+  set(CPACK_PACKAGE_VENDOR "http://warp.povusers.org/FunctionParser/")
>+  set(CPACK_PACKAGE_DISPLAY_NAME "fparser ${FPARSER_VERSION}")
>+  set(CPACK_PACKAGE_DESCRIPTION_SUMMARY " - Function Parser (http://warp.povusers.org/FunctionParser)")
>+  set(CPACK_PACKAGE_VERSION ${FPARSER_VERSION}.${PACKAGE_VERSION})
>+  set(CPACK_PACKAGE_VERSION_MAJOR ${FPARSER_VERSION_MAJOR})
>+  set(CPACK_PACKAGE_VERSION_MINOR ${FPARSER_VERSION_MINOR})
>+  set(CPACK_PACKAGE_VERSION_PATCH ${FPARSER_VERSION_PATCH})
>+  set(CPACK_PACKAGE_INSTALL_DIRECTORY "fparser")
>+  #set(CPACK_PACKAGE_DESCRIPTION_FILE ${CMAKE_CURRENT_SOURCE_DIR}/description)
>+  #set(CPACK_RESOURCE_FILE_LICENSE ${CMAKE_CURRENT_SOURCE_DIR}/dom/license.txt)
>+
>+  set(CPACK_COMPONENT_LIBFPARSER${FPARSER_SOVERSION}_DISPLAY_NAME "core library binaries")
>+  set(CPACK_COMPONENT_FPARSER-DEV_DISPLAY_NAME "development headers and build files")
>+  set(CPACK_COMPONENT_FPARSER-DEV_DEPENDS libfparser${FPARSER_SOVERSION})
>+
>+  set(CPACK_DEBIAN_BUILD_DEPENDS debhelper cmake pkg-config libmpfr-dev libgmp3-dev )
>+  set(CPACK_COMPONENTS_ALL libfparser${FPARSER_SOVERSION} fparser-dev)
>+
>+  # debian
>+  set(CPACK_DEBIAN_PACKAGE_PRIORITY optional)
>+  set(CPACK_DEBIAN_PACKAGE_SECTION libs)
>+  set(CPACK_DEBIAN_PACKAGE_DEPENDS ${CPACK_COMPONENTS_ALL})
>+  set(CPACK_DEBIAN_PACKAGE_SUGGESTS)
>+  set(CPACK_DEBIAN_PACKAGE_NAME fparser)
>+  set(CPACK_DEBIAN_PACKAGE_REMOVE_SOURCE_FILES )
>+  set(CPACK_DEBIAN_PACKAGE_SOURCE_COPY cp -r)#svn export --force)
>+  set(CPACK_DEBIAN_CHANGELOG)
>+  execute_process(COMMAND lsb_release -is
>+    OUTPUT_VARIABLE _lsb_distribution OUTPUT_STRIP_TRAILING_WHITESPACE
>+    RESULT_VARIABLE _lsb_release_failed)
>+  set(CPACK_DEBIAN_DISTRIBUTION_NAME ${_lsb_distribution} CACHE STRING "Name of the distrubiton")
>+  string(TOLOWER ${CPACK_DEBIAN_DISTRIBUTION_NAME} CPACK_DEBIAN_DISTRIBUTION_NAME)
>+  if( ${CPACK_DEBIAN_DISTRIBUTION_NAME} STREQUAL "ubuntu" )
>+    set(CPACK_DEBIAN_DISTRIBUTION_RELEASES lucid maverick natty oneiric precise CACHE STRING "Release code-names of the distrubiton release")
>+  endif()
>+  set(CPACK_COMPONENT_FPARSER_DEPENDS ${CPACK_COMPONENTS_ALL})
>+  set(DPUT_HOST "" CACHE STRING "PPA repository to upload the debian sources")
>+  include(CPack)
>+  include(DebSourcePPA)
>+endif()
>diff -urN fparser.orig/extrasrc/fptypes.hh fparser/extrasrc/fptypes.hh
>--- fparser.orig/extrasrc/fptypes.hh	2012-11-11 09:25:15.000000000 +0100
>+++ fparser/extrasrc/fptypes.hh	2014-02-24 15:48:06.423294333 +0100
>@@ -16,7 +16,7 @@
> #ifndef ONCE_FPARSER_TYPES_H_
> #define ONCE_FPARSER_TYPES_H_
> 
>-#include "../fpconfig.hh"
>+#include "fpconfig.hh"
> #include <cstring>
> 
> #ifdef ONCE_FPARSER_H_
>diff -urN fparser.orig/fparser-config.cmake.in fparser/fparser-config.cmake.in
>--- fparser.orig/fparser-config.cmake.in	1970-01-01 01:00:00.000000000 +0100
>+++ fparser/fparser-config.cmake.in	2014-02-24 15:45:56.567787451 +0100
>@@ -0,0 +1,51 @@
>+# - Find FunctionParser Installation
>+#
>+# Users can set the following variables before calling the module:
>+#  FPARSER_DIR - The preferred installation prefix for searching for FPARSER. Set by the user.
>+#
>+# FPARSER_ROOT_DIR - the root directory where the installation can be found
>+# FPARSER_CXX_FLAGS - extra flags for compilation
>+# FPARSER_LINK_FLAGS - extra flags for linking
>+# FPARSER_INCLUDE_DIRS - include directories
>+# FPARSER_LIBRARY_DIRS - link directories
>+# FPARSER_LIBRARIES - libraries to link plugins with
>+get_filename_component(_PREFIX "${CMAKE_CURRENT_LIST_FILE}" PATH)
>+get_filename_component(_PREFIX "${_PREFIX}" PATH)
>+get_filename_component(_PREFIX "${_PREFIX}" PATH)
>+get_filename_component(FPARSER_ROOT_DIR "${_PREFIX}" PATH)
>+
>+if( MSVC )
>+  # in order to prevent DLL hell, each of the DLLs have to be suffixed with the major version and msvc prefix
>+  if( MSVC70 OR MSVC71 )
>+    set(MSVC_PREFIX "vc70")
>+  elseif( MSVC80 )
>+    set(MSVC_PREFIX "vc80")
>+  elseif( MSVC90 )
>+    set(MSVC_PREFIX "vc90")
>+  else()
>+    set(MSVC_PREFIX "vc100")
>+  endif()
>+  set(FPARSER_LIBRARY_SUFFIX "${FPARSER_VERSION_MAJOR}.${FPARSER_VERSION_MINOR}.${FPARSER_VERSION_PATCH}-${MSVC_PREFIX}-mt" CACHE STRING "the suffix for the fparser library" FORCE)
>+else()
>+  set(FPARSER_LIBRARY_SUFFIX "${FPARSER_VERSION_MAJOR}.${FPARSER_VERSION_MINOR}.${FPARSER_VERSION_PATCH}")
>+endif()
>+
>+set( FPARSER_LINK_FLAGS "" )
>+set( FPARSER_LIBRARY_DIRS "${FPARSER_ROOT_DIR}/lib@LIB_SUFFIX@")
>+set( FPARSER_INCLUDE_DIRS "${FPARSER_ROOT_DIR}/@FPARSER_INCLUDE_INSTALL_DIR@")
>+set( FPARSER_LIBRARIES fparser${FPARSER_LIBRARY_SUFFIX})
>+
>+# for compatibility wiht pkg-config
>+set(FPARSER_CFLAGS_OTHER "${FPARSER_CXX_FLAGS}")
>+set(FPARSER_LDFLAGS_OTHER "${FPARSER_LINK_FLAGS}")
>+
>+MARK_AS_ADVANCED(
>+  FPARSER_ROOT_DIR
>+  FPARSER_CXX_FLAGS
>+  FPARSER_LINK_FLAGS
>+  FPARSER_INCLUDE_DIRS
>+  FPARSER_LIBRARIES
>+  FPARSER_CFLAGS_OTHER
>+  FPARSER_LDFLAGS_OTHER
>+  FPARSER_LIBRARY_SUFFIX
>+)
>diff -urN fparser.orig/fparser-config-version.cmake.in fparser/fparser-config-version.cmake.in
>--- fparser.orig/fparser-config-version.cmake.in	1970-01-01 01:00:00.000000000 +0100
>+++ fparser/fparser-config-version.cmake.in	2014-02-24 15:45:56.572787276 +0100
>@@ -0,0 +1,7 @@
>+set(PACKAGE_VERSION "@FPARSER_VERSION@")
>+if( "${PACKAGE_FIND_VERSION}" VERSION_EQUAL "@FPARSER_VERSION@" )
>+  set(PACKAGE_VERSION_EXACT 1)
>+endif()
>+if( "$(PACKAGE_FIND_VERSION.MAJOR}.${PACKAGE_FIND_VERSION_MINOR}.${PACKAGE_FIND_VERSION_PATCH}" STRLESS "@FPARSER_VERSION@")
>+  set(PACKAGE_VERSION_COMPATIBLE 1)
>+endif()
>diff -urN fparser.orig/fpconfig.hh.in fparser/fpconfig.hh.in
>--- fparser.orig/fpconfig.hh.in	1970-01-01 01:00:00.000000000 +0100
>+++ fparser/fpconfig.hh.in	2014-02-24 15:45:56.576787136 +0100
>@@ -0,0 +1,90 @@
>+/***************************************************************************\
>+|* Function Parser for C++ v4.5                                            *|
>+|*|*|*|*|*|*|*|*|*|*|*-------------------------------------------------------------------------*|
>+|* Copyright: Juha Nieminen                                                *|
>+|*                                                                         *|
>+|* This library is distributed under the terms of the                      *|
>+|* GNU Lesser General Public License version 3.                            *|
>+|* (See lgpl.txt and gpl.txt for the license text.)                        *|
>+\***************************************************************************/
>+
>+// Configuration file
>+// ------------------
>+
>+/* NOTE:
>+   This file is for the internal use of the function parser only.
>+   You don't need to include this file in your source files, just
>+   include "fparser.hh".
>+ */
>+
>+
>+/* Uncomment any of these lines or define them in your compiler settings
>+   to enable the correspondent version of the parser. (These are disabled
>+   by default because they rely on C99 functions, and non-standard libraries
>+   in the case pf MPFR and GMP, and they make compiling needlessly slower
>+   and the resulting binary needlessly larger if they are not used in the
>+   program.)
>+ */
>+#cmakedefine FP_SUPPORT_FLOAT_TYPE
>+#cmakedefine FP_SUPPORT_LONG_DOUBLE_TYPE
>+#cmakedefine FP_SUPPORT_LONG_INT_TYPE
>+#cmakedefine FP_SUPPORT_MPFR_FLOAT_TYPE
>+#cmakedefine FP_SUPPORT_GMP_INT_TYPE
>+#cmakedefine FP_SUPPORT_COMPLEX_DOUBLE_TYPE
>+#cmakedefine FP_SUPPORT_COMPLEX_FLOAT_TYPE
>+#cmakedefine FP_SUPPORT_COMPLEX_LONG_DOUBLE_TYPE
>+#cmakedefine FP_USE_STRTOF
>+#cmakedefine FP_USE_STRTOLD
>+
>+/* Uncomment this line of define it in your compiler settings if you want
>+   to disable compiling the basic double version of the library, in case
>+   one of the above types is used but not the double type. (If the double
>+   type is not used, then disabling it makes compiling faster and the
>+   resulting binary smaller.)
>+ */
>+#cmakedefine FP_DISABLE_DOUBLE_TYPE
>+
>+/*
>+   Whether to use shortcut evaluation for the & and | operators:
>+ */
>+#cmakedefine FP_ENABLE_SHORTCUT_LOGICAL_EVALUATION
>+
>+/*
>+   Whether to enable optimizations that may ignore side effects
>+   of if() calls, such as changing if(x,!y,0) into x&!y.
>+   This is basically the polar opposite of "shortcut logical evaluation".
>+   Disabled by default, because it makes eval() rather unsafe.
>+ */
>+#ifdef FP_ENABLE_IGNORE_IF_SIDEEFFECTS
>+#endif
>+
>+/*
>+   Comment out the following lines out if you are not going to use the
>+   optimizer and want a slightly smaller library. The Optimize() method
>+   can still be called, but it will not do anything.
>+   If you are unsure, just leave it. It won't slow down the other parts of
>+   the library.
>+ */
>+#cmakedefine FP_SUPPORT_OPTIMIZER
>+
>+#if defined(FP_SUPPORT_COMPLEX_DOUBLE_TYPE) || defined(FP_SUPPORT_COMPLEX_FLOAT_TYPE) || defined(FP_SUPPORT_COMPLEX_LONG_DOUBLE_TYPE)
>+#define FP_SUPPORT_COMPLEX_NUMBERS
>+#endif
>+
>+
>+/*
>+   No member function of FunctionParser is thread-safe. Most prominently,
>+   Eval() is not thread-safe. By uncommenting one of these lines the Eval()
>+   function can be made thread-safe at the cost of a possible small overhead.
>+   The second version requires that the compiler supports the alloca() function,
>+   which is not standard, but is faster.
>+ */
>+#cmakedefine FP_USE_THREAD_SAFE_EVAL
>+#cmakedefine FP_USE_THREAD_SAFE_EVAL_WITH_ALLOCA
>+
>+/*
>+   Uncomment (or define in your compiler options) to disable evaluation checks.
>+   (Consult the documentation for details.)
>+ */
>+#cmakedefine FP_NO_EVALUATION_CHECKS
>+
>diff -urN fparser.orig/modules-cmake/CGAL_FindPackageHandleStandardArgs.cmake fparser/modules-cmake/CGAL_FindPackageHandleStandardArgs.cmake
>--- fparser.orig/modules-cmake/CGAL_FindPackageHandleStandardArgs.cmake	1970-01-01 01:00:00.000000000 +0100
>+++ fparser/modules-cmake/CGAL_FindPackageHandleStandardArgs.cmake	2014-02-24 15:46:03.936532535 +0100
>@@ -0,0 +1,55 @@
>+# FIND_PACKAGE_HANDLE_STANDARD_ARGS(NAME (DEFAULT_MSG|"Custom failure message") VAR1 ... )
>+#    This macro is intended to be used in FindXXX.cmake modules files.
>+#    It handles the REQUIRED and QUIET argument to FIND_PACKAGE() and
>+#    it also sets the <UPPERCASED_NAME>_FOUND variable.
>+#    The package is found if all variables listed are TRUE.
>+#    Example:
>+#
>+#    FIND_PACKAGE_HANDLE_STANDARD_ARGS(LibXml2 DEFAULT_MSG LIBXML2_LIBRARIES LIBXML2_INCLUDE_DIR)
>+#
>+#    LibXml2 is considered to be found, if both LIBXML2_LIBRARIES and 
>+#    LIBXML2_INCLUDE_DIR are valid. Then also LIBXML2_FOUND is set to TRUE.
>+#    If it is not found and REQUIRED was used, it fails with FATAL_ERROR, 
>+#    independent whether QUIET was used or not.
>+#    If it is found, the location is reported using the VAR1 argument, so 
>+#    here a message "Found LibXml2: /usr/lib/libxml2.so" will be printed out.
>+#    If the second argument is DEFAULT_MSG, the message in the failure case will 
>+#    be "Could NOT find LibXml2", if you don't like this message you can specify
>+#    your own custom failure message there.
>+
>+macro(FIND_PACKAGE_HANDLE_STANDARD_ARGS _NAME _FAIL_MSG _VAR1 )
>+
>+  if("${_FAIL_MSG}" STREQUAL "DEFAULT_MSG")
>+    set(_FAIL_MESSAGE "Could NOT find ${_NAME}")
>+  else()
>+    set(_FAIL_MESSAGE "${_FAIL_MSG}")
>+  endif()
>+
>+  string(TOUPPER ${_NAME} _NAME_UPPER)
>+
>+  set(${_NAME_UPPER}_FOUND TRUE)
>+  if(NOT ${_VAR1})
>+    set(${_NAME_UPPER}_FOUND FALSE)
>+  endif()
>+
>+  foreach(_CURRENT_VAR ${ARGN})
>+    if(NOT ${_CURRENT_VAR})
>+      set(${_NAME_UPPER}_FOUND FALSE)
>+    endif()
>+  endforeach()
>+  
>+  if (${_NAME_UPPER}_FOUND)
>+    if (NOT ${_NAME}_FIND_QUIETLY)
>+      message(STATUS "Found ${_NAME}: ${${_VAR1}}")
>+    endif()
>+  else()
>+    if (${_NAME}_FIND_REQUIRED)
>+      message(FATAL_ERROR "${_FAIL_MESSAGE}")
>+    else()
>+      if (NOT ${_NAME}_FIND_QUIETLY)
>+        message(STATUS "${_FAIL_MESSAGE}")
>+      endif()
>+    endif()
>+  endif()
>+  
>+endmacro()
>diff -urN fparser.orig/modules-cmake/CGAL_GeneratorSpecificSettings.cmake fparser/modules-cmake/CGAL_GeneratorSpecificSettings.cmake
>--- fparser.orig/modules-cmake/CGAL_GeneratorSpecificSettings.cmake	1970-01-01 01:00:00.000000000 +0100
>+++ fparser/modules-cmake/CGAL_GeneratorSpecificSettings.cmake	2014-02-24 15:46:03.920533095 +0100
>@@ -0,0 +1,54 @@
>+if ( NOT CGAL_GENERATOR_SPECIFIC_SETTINGS_FILE_INCLUDED )
>+  set( CGAL_GENERATOR_SPECIFIC_SETTINGS_FILE_INCLUDED 1 )
>+ 
>+  message( STATUS "Targetting ${CMAKE_GENERATOR}")
>+  
>+  if ( MSVC )
>+    message( STATUS "Target build enviroment supports auto-linking" )
>+    set(CGAL_AUTO_LINK_ENABLED TRUE)
>+
>+    if(NOT CGAL_CONFIG_LOADED)
>+      set(CGAL_AUTO_LINK_GMP FALSE
>+        CACHE BOOL "Enable/Disable auto-linking for the external library GMP")
>+
>+      set(CGAL_AUTO_LINK_MPFR FALSE
>+        CACHE BOOL "Enable/Disable auto-linking for the external library MPFR")
>+
>+      mark_as_advanced(CGAL_AUTO_LINK_MPFR CGAL_AUTO_LINK_GMP)
>+    endif()
>+  endif()
>+
>+  if ( MSVC10 )  
>+    set(CGAL_TOOLSET "vc100")
>+    message( STATUS "Using VC10 compiler." )
>+  elseif ( MSVC90 )  
>+    set(CGAL_TOOLSET "vc90")
>+    message( STATUS "Using VC90 compiler." )
>+  elseif ( MSVC80 )  
>+    set(CGAL_TOOLSET "vc80")
>+    message( STATUS "Using VC80 compiler." )
>+  elseif ( MSVC71 )
>+    set(CGAL_TOOLSET "vc71")
>+    message( STATUS "Using VC71 compiler." )
>+  else()
>+    message( STATUS "Using ${CMAKE_CXX_COMPILER} compiler." )
>+  endif()
>+
>+  
>+  # From james Bigler, in the cmake users list.
>+  IF (APPLE)
>+    exec_program(uname ARGS -v  OUTPUT_VARIABLE DARWIN_VERSION)
>+    string(REGEX MATCH "[0-9]+" DARWIN_VERSION ${DARWIN_VERSION})
>+    message(STATUS "DARWIN_VERSION=${DARWIN_VERSION}")
>+    if (DARWIN_VERSION GREATER 8)
>+       message(STATUS "Mac Leopard detected")
>+      set(CGAL_APPLE_LEOPARD 1)
>+    endif()
>+  endif()
>+  
>+  if ( NOT "${CMAKE_CFG_INTDIR}" STREQUAL "." )
>+    set(HAS_CFG_INTDIR TRUE CACHE INTERNAL "Generator uses intermediate configuration directory" )
>+    message( STATUS "Generator uses intermediate configuration directory: ${CMAKE_CFG_INTDIR}" )
>+  endif()
>+
>+endif()
>diff -urN fparser.orig/modules-cmake/cmake_uninstall.cmake.in fparser/modules-cmake/cmake_uninstall.cmake.in
>--- fparser.orig/modules-cmake/cmake_uninstall.cmake.in	1970-01-01 01:00:00.000000000 +0100
>+++ fparser/modules-cmake/cmake_uninstall.cmake.in	2014-02-24 15:46:03.932532675 +0100
>@@ -0,0 +1,17 @@
>+IF(NOT EXISTS "@CMAKE_CURRENT_BINARY_DIR@/install_manifest.txt")
>+  MESSAGE(FATAL_ERROR "Cannot find install manifest: \"@CMAKE_CURRENT_BINARY_DIR@/install_manifest.txt\"")
>+ENDIF(NOT EXISTS "@CMAKE_CURRENT_BINARY_DIR@/install_manifest.txt")
>+
>+FILE(READ "@CMAKE_CURRENT_BINARY_DIR@/install_manifest.txt" files)
>+STRING(REGEX REPLACE "\n" ";" files "${files}")
>+FOREACH(file ${files})
>+  MESSAGE(STATUS "Uninstalling \"$ENV{DESTDIR}${file}\"")
>+  EXEC_PROGRAM(
>+    "@CMAKE_COMMAND@" ARGS "-E remove \"$ENV{DESTDIR}${file}\""
>+    OUTPUT_VARIABLE rm_out
>+    RETURN_VALUE rm_retval
>+    )
>+  IF(NOT "${rm_retval}" STREQUAL 0)
>+    MESSAGE(FATAL_ERROR "Problem when removing \"$ENV{DESTDIR}${file}\"")
>+  ENDIF(NOT "${rm_retval}" STREQUAL 0)
>+ENDFOREACH(file)
>diff -urN fparser.orig/modules-cmake/DebSourcePPA.cmake fparser/modules-cmake/DebSourcePPA.cmake
>--- fparser.orig/modules-cmake/DebSourcePPA.cmake	1970-01-01 01:00:00.000000000 +0100
>+++ fparser/modules-cmake/DebSourcePPA.cmake	2014-02-24 15:46:03.928532815 +0100
>@@ -0,0 +1,279 @@
>+## Debian Source Package Generator
>+#
>+# Copyright (c) 2010 Daniel Pfeifer <daniel@pfeifer-mail.de>
>+# Many modifications by Rosen Diankov <rosen.diankov@gmail.com>
>+#
>+# Creates source debian files and manages library dependencies
>+#
>+# Features:
>+# 
>+# - Automatically generates symbols and run-time dependencies from the build dependencies
>+# - Custom copy of source directory via CPACK_DEBIAN_PACKAGE_SOURCE_COPY
>+# - Simultaneous output of multiple debian source packages for each distribution
>+# - Can specificy distribution-specific dependencies by suffixing DEPENDS with _${DISTRO_NAME}, for example: CPACK_DEBIAN_PACKAGE_DEPENDS_LUCID, CPACK_COMPONENT_MYCOMP0_DEPENDS_LUCID
>+#
>+# Usage:
>+#
>+# set(CPACK_DEBIAN_BUILD_DEPENDS debhelper cmake)
>+# set(CPACK_DEBIAN_PACKAGE_PRIORITY optional)
>+# set(CPACK_DEBIAN_PACKAGE_SECTION devel)
>+# set(CPACK_DEBIAN_CMAKE_OPTIONS "-DMYOPTION=myvalue")
>+# set(CPACK_DEBIAN_PACKAGE_DEPENDS mycomp0 mycomp1 some_ubuntu_package)
>+# set(CPACK_DEBIAN_PACKAGE_DEPENDS_UBUNTU_LUCID mycomp0 mycomp1 lucid_specific_package)
>+# set(CPACK_DEBIAN_PACKAGE_NAME mypackage)
>+# set(CPACK_DEBIAN_PACKAGE_REMOVE_SOURCE_FILES unnecessary_file unnecessary_dir/file0)
>+# set(CPACK_DEBIAN_PACKAGE_SOURCE_COPY svn export --force) # if using subversion
>+# set(CPACK_DEBIAN_DISTRIBUTION_NAME ubuntu)
>+# set(CPACK_DEBIAN_DISTRIBUTION_RELEASES karmic lucid maverick natty)
>+# set(CPACK_DEBIAN_CHANGELOG "  * Extra change log lines")
>+# set(CPACK_DEBIAN_PACKAGE_RECOMMENDS "ipython")
>+# set(CPACK_COMPONENT_X_RECOMMENDS "recommended-package")
>+##
>+
>+find_program(DEBUILD_EXECUTABLE debuild)
>+find_program(DPUT_EXECUTABLE dput)
>+
>+if(NOT DEBUILD_EXECUTABLE OR NOT DPUT_EXECUTABLE)
>+  return()
>+endif(NOT DEBUILD_EXECUTABLE OR NOT DPUT_EXECUTABLE)
>+
>+# DEBIAN/control
>+# debian policy enforce lower case for package name
>+# Package: (mandatory)
>+IF(NOT CPACK_DEBIAN_PACKAGE_NAME)
>+  STRING(TOLOWER "${CPACK_PACKAGE_NAME}" CPACK_DEBIAN_PACKAGE_NAME)
>+ENDIF(NOT CPACK_DEBIAN_PACKAGE_NAME)
>+
>+# Section: (recommended)
>+IF(NOT CPACK_DEBIAN_PACKAGE_SECTION)
>+  SET(CPACK_DEBIAN_PACKAGE_SECTION "devel")
>+ENDIF(NOT CPACK_DEBIAN_PACKAGE_SECTION)
>+
>+# Priority: (recommended)
>+IF(NOT CPACK_DEBIAN_PACKAGE_PRIORITY)
>+  SET(CPACK_DEBIAN_PACKAGE_PRIORITY "optional")
>+ENDIF(NOT CPACK_DEBIAN_PACKAGE_PRIORITY)
>+
>+file(STRINGS ${CPACK_PACKAGE_DESCRIPTION_FILE} DESC_LINES)
>+foreach(LINE ${DESC_LINES})
>+  set(DEB_LONG_DESCRIPTION "${DEB_LONG_DESCRIPTION} ${LINE}\n")
>+endforeach(LINE ${DESC_LINES})
>+
>+file(REMOVE_RECURSE "${CMAKE_BINARY_DIR}/Debian")
>+file(MAKE_DIRECTORY "${CMAKE_BINARY_DIR}/Debian")
>+set(DEBIAN_SOURCE_ORIG_DIR "${CMAKE_BINARY_DIR}/Debian/${CPACK_DEBIAN_PACKAGE_NAME}-${CPACK_PACKAGE_VERSION}")
>+
>+if( CPACK_DEBIAN_PACKAGE_SOURCE_COPY )
>+  execute_process(COMMAND ${CPACK_DEBIAN_PACKAGE_SOURCE_COPY} "${CMAKE_SOURCE_DIR}" "${DEBIAN_SOURCE_ORIG_DIR}.orig")
>+else()
>+  execute_process(COMMAND ${CMAKE_COMMAND} -E copy_directory ${CMAKE_SOURCE_DIR} "${DEBIAN_SOURCE_ORIG_DIR}.orig")
>+  execute_process(COMMAND ${CMAKE_COMMAND} -E remove_directory "${DEBIAN_SOURCE_ORIG_DIR}.orig/.git")
>+  execute_process(COMMAND ${CMAKE_COMMAND} -E remove_directory "${DEBIAN_SOURCE_ORIG_DIR}.orig/.svn")
>+endif()
>+
>+# remove unnecessary folders
>+foreach(REMOVE_DIR ${CPACK_DEBIAN_PACKAGE_REMOVE_SOURCE_FILES})
>+  file(REMOVE_RECURSE ${DEBIAN_SOURCE_ORIG_DIR}.orig/${REMOVE_DIR})
>+endforeach()
>+
>+# create the original source tar
>+execute_process(COMMAND ${CMAKE_COMMAND} -E tar czf "${CPACK_DEBIAN_PACKAGE_NAME}_${CPACK_PACKAGE_VERSION}.orig.tar.gz" "${CPACK_DEBIAN_PACKAGE_NAME}-${CPACK_PACKAGE_VERSION}.orig" WORKING_DIRECTORY ${CMAKE_BINARY_DIR}/Debian)
>+
>+set(DEB_SOURCE_CHANGES)
>+foreach(RELEASE ${CPACK_DEBIAN_DISTRIBUTION_RELEASES})
>+  set(DEBIAN_SOURCE_DIR "${DEBIAN_SOURCE_ORIG_DIR}-${CPACK_DEBIAN_DISTRIBUTION_NAME}1~${RELEASE}1")
>+  set(RELEASE_PACKAGE_VERSION "${CPACK_PACKAGE_VERSION}-${CPACK_DEBIAN_DISTRIBUTION_NAME}1~${RELEASE}1")
>+  string(TOUPPER ${RELEASE} RELEASE_UPPER)
>+  string(TOUPPER ${CPACK_DEBIAN_DISTRIBUTION_NAME} DISTRIBUTION_NAME_UPPER)
>+  file(MAKE_DIRECTORY ${DEBIAN_SOURCE_DIR}/debian)
>+  ##############################################################################
>+  # debian/control
>+  set(DEBIAN_CONTROL ${DEBIAN_SOURCE_DIR}/debian/control)
>+  file(WRITE ${DEBIAN_CONTROL}
>+    "Source: ${CPACK_DEBIAN_PACKAGE_NAME}\n"
>+    "Section: ${CPACK_DEBIAN_PACKAGE_SECTION}\n"
>+    "Priority: ${CPACK_DEBIAN_PACKAGE_PRIORITY}\n"
>+    "DM-Upload-Allowed: yes\n"
>+    "Maintainer: ${CPACK_PACKAGE_CONTACT}\n"
>+    "Build-Depends: "
>+    )
>+
>+  if( CPACK_DEBIAN_BUILD_DEPENDS_${DISTRIBUTION_NAME_UPPER}_${RELEASE_UPPER} )
>+    foreach(DEP ${CPACK_DEBIAN_BUILD_DEPENDS_${DISTRIBUTION_NAME_UPPER}_${RELEASE_UPPER}})
>+      file(APPEND ${DEBIAN_CONTROL} "${DEP}, ")
>+    endforeach(DEP ${CPACK_DEBIAN_BUILD_DEPENDS_${DISTRIBUTION_NAME_UPPER}_${RELEASE_UPPER}})
>+  else( CPACK_DEBIAN_BUILD_DEPENDS_${DISTRIBUTION_NAME_UPPER}_${RELEASE_UPPER} )
>+    if( CPACK_DEBIAN_BUILD_DEPENDS_${DISTRIBUTION_NAME_UPPER} )
>+      foreach(DEP ${CPACK_DEBIAN_BUILD_DEPENDS_${DISTRIBUTION_NAME_UPPER}})
>+        file(APPEND ${DEBIAN_CONTROL} "${DEP}, ")
>+      endforeach(DEP ${CPACK_DEBIAN_BUILD_DEPENDS_${DISTRIBUTION_NAME_UPPER}})
>+    else( CPACK_DEBIAN_BUILD_DEPENDS_${DISTRIBUTION_NAME_UPPER} )
>+      foreach(DEP ${CPACK_DEBIAN_BUILD_DEPENDS})
>+        file(APPEND ${DEBIAN_CONTROL} "${DEP}, ")
>+      endforeach(DEP ${CPACK_DEBIAN_BUILD_DEPENDS})
>+    endif( CPACK_DEBIAN_BUILD_DEPENDS_${DISTRIBUTION_NAME_UPPER} )
>+  endif( CPACK_DEBIAN_BUILD_DEPENDS_${DISTRIBUTION_NAME_UPPER}_${RELEASE_UPPER} )
>+
>+    
>+  file(APPEND ${DEBIAN_CONTROL} "\n"
>+    "Standards-Version: 3.8.4\n"
>+    "Homepage: ${CPACK_PACKAGE_VENDOR}\n"
>+    "\n"
>+    "Package: ${CPACK_DEBIAN_PACKAGE_NAME}\n"
>+    "Architecture: any\n"
>+    "Recommends: ${CPACK_DEBIAN_PACKAGE_RECOMMENDS}\n"
>+    "Depends: "
>+    )
>+
>+  if( CPACK_DEBIAN_PACKAGE_DEPENDS_${DISTRIBUTION_NAME_UPPER}_${RELEASE_UPPER} )
>+    foreach(DEP ${CPACK_DEBIAN_PACKAGE_DEPENDS_${DISTRIBUTION_NAME_UPPER}_${RELEASE_UPPER}})
>+      file(APPEND ${DEBIAN_CONTROL} "${DEP}, ")
>+    endforeach(DEP ${CPACK_DEBIAN_PACKAGE_DEPENDS_${DISTRIBUTION_NAME_UPPER}_${RELEASE_UPPER}})
>+  else( CPACK_DEBIAN_PACKAGE_DEPENDS_${DISTRIBUTION_NAME_UPPER}_${RELEASE_UPPER} )
>+    if( CPACK_DEBIAN_PACKAGE_DEPENDS_${DISTRIBUTION_NAME_UPPER} )
>+      foreach(DEP ${CPACK_DEBIAN_PACKAGE_DEPENDS_${DISTRIBUTION_NAME_UPPER}})
>+        file(APPEND ${DEBIAN_CONTROL} "${DEP}, ")
>+      endforeach(DEP ${CPACK_DEBIAN_PACKAGE_DEPENDS_${DISTRIBUTION_NAME_UPPER}})
>+    else( CPACK_DEBIAN_PACKAGE_DEPENDS_${DISTRIBUTION_NAME_UPPER} )
>+      foreach(DEP ${CPACK_DEBIAN_PACKAGE_DEPENDS})
>+        file(APPEND ${DEBIAN_CONTROL} "${DEP}, ")
>+      endforeach(DEP ${CPACK_DEBIAN_PACKAGE_DEPENDS})
>+    endif( CPACK_DEBIAN_PACKAGE_DEPENDS_${DISTRIBUTION_NAME_UPPER} )
>+  endif( CPACK_DEBIAN_PACKAGE_DEPENDS_${DISTRIBUTION_NAME_UPPER}_${RELEASE_UPPER} )
>+  
>+  file(APPEND ${DEBIAN_CONTROL} "\n"
>+    "Description: ${CPACK_PACKAGE_DISPLAY_NAME} ${CPACK_PACKAGE_DESCRIPTION_SUMMARY}\n"
>+    "${DEB_LONG_DESCRIPTION}"
>+    )
>+
>+  foreach(COMPONENT ${CPACK_COMPONENTS_ALL})
>+    string(TOUPPER ${COMPONENT} UPPER_COMPONENT)
>+    set(DEPENDS "\${shlibs:Depends}")
>+    if( CPACK_COMPONENT_${UPPER_COMPONENT}_DEPENDS_${DISTRIBUTION_NAME_UPPER}_${RELEASE_UPPER} )
>+      foreach(DEP ${CPACK_COMPONENT_${UPPER_COMPONENT}_DEPENDS_${DISTRIBUTION_NAME_UPPER}_${RELEASE_UPPER}})
>+        set(DEPENDS "${DEPENDS}, ${DEP}")
>+      endforeach(DEP ${CPACK_COMPONENT_${UPPER_COMPONENT}_DEPENDS_${DISTRIBUTION_NAME_UPPER}_${RELEASE_UPPER}})
>+    else( CPACK_COMPONENT_${UPPER_COMPONENT}_DEPENDS_${DISTRIBUTION_NAME_UPPER}_${RELEASE_UPPER} )
>+      if( CPACK_COMPONENT_${UPPER_COMPONENT}_DEPENDS_${DISTRIBUTION_NAME_UPPER} )
>+        foreach(DEP ${CPACK_COMPONENT_${UPPER_COMPONENT}_DEPENDS_${DISTRIBUTION_NAME_UPPER}})
>+          set(DEPENDS "${DEPENDS}, ${DEP}")
>+        endforeach(DEP ${CPACK_COMPONENT_${UPPER_COMPONENT}_DEPENDS_${DISTRIBUTION_NAME_UPPER}})
>+      else( CPACK_COMPONENT_${UPPER_COMPONENT}_DEPENDS_${DISTRIBUTION_NAME_UPPER} )
>+        foreach(DEP ${CPACK_COMPONENT_${UPPER_COMPONENT}_DEPENDS})
>+          set(DEPENDS "${DEPENDS}, ${DEP}")
>+        endforeach(DEP ${CPACK_COMPONENT_${UPPER_COMPONENT}_DEPENDS})
>+      endif( CPACK_COMPONENT_${UPPER_COMPONENT}_DEPENDS_${DISTRIBUTION_NAME_UPPER} )
>+    endif( CPACK_COMPONENT_${UPPER_COMPONENT}_DEPENDS_${DISTRIBUTION_NAME_UPPER}_${RELEASE_UPPER} )
>+
>+    file(APPEND ${DEBIAN_CONTROL} "\n"
>+      "Package: ${COMPONENT}\n"
>+      "Architecture: any\n"
>+      "Depends: ${DEPENDS}\n"
>+      "Recommends: ${CPACK_COMPONENT_${UPPER_COMPONENT}_RECOMMENDS}\n"
>+      "Description: ${CPACK_PACKAGE_DISPLAY_NAME} ${CPACK_COMPONENT_${UPPER_COMPONENT}_DISPLAY_NAME}\n"
>+      "${DEB_LONG_DESCRIPTION}"
>+      " .\n"
>+      " ${CPACK_COMPONENT_${UPPER_COMPONENT}_DESCRIPTION}\n"
>+      )
>+  endforeach(COMPONENT ${CPACK_COMPONENTS_ALL})
>+
>+  ##############################################################################
>+  # debian/copyright
>+  set(DEBIAN_COPYRIGHT ${DEBIAN_SOURCE_DIR}/debian/copyright)
>+  execute_process(COMMAND ${CMAKE_COMMAND} -E
>+    copy ${CPACK_RESOURCE_FILE_LICENSE} ${DEBIAN_COPYRIGHT}
>+    )
>+
>+  ##############################################################################
>+  # debian/rules
>+  set(DEBIAN_RULES ${DEBIAN_SOURCE_DIR}/debian/rules)
>+  file(WRITE ${DEBIAN_RULES}
>+    "#!/usr/bin/make -f\n"
>+    "\n"
>+    "BUILDDIR = build_dir\n"
>+    "\n"
>+    "build:\n"
>+    "	mkdir $(BUILDDIR)\n"
>+    "	cd $(BUILDDIR); cmake -DCMAKE_BUILD_TYPE=Release ${CPACK_DEBIAN_CMAKE_OPTIONS} -DCMAKE_INSTALL_PREFIX=/usr ..\n"
>+    "	$(MAKE) -C $(BUILDDIR) preinstall\n"
>+    "	touch build\n"
>+    "\n"
>+    "binary: binary-indep binary-arch\n"
>+    "\n"
>+    "binary-indep: build\n"
>+    "\n"
>+    "binary-arch: build\n"
>+    "	cd $(BUILDDIR); cmake -DCOMPONENT=Unspecified -DCMAKE_INSTALL_PREFIX=../debian/tmp/usr -P cmake_install.cmake\n"
>+    "	mkdir -p debian/tmp/DEBIAN\n"
>+    "	dpkg-gensymbols -p${CPACK_DEBIAN_PACKAGE_NAME}\n"
>+    )
>+
>+  foreach(COMPONENT ${CPACK_COMPONENTS_ALL})
>+    set(PATH debian/${COMPONENT})
>+    file(APPEND ${DEBIAN_RULES}
>+      "	cd $(BUILDDIR); cmake -DCOMPONENT=${COMPONENT} -DCMAKE_INSTALL_PREFIX=../${PATH}/usr -P cmake_install.cmake\n"
>+      "	mkdir -p ${PATH}/DEBIAN\n"
>+      "	dpkg-gensymbols -p${COMPONENT} -P${PATH}\n"
>+      )
>+  endforeach(COMPONENT ${CPACK_COMPONENTS_ALL})
>+
>+  file(APPEND ${DEBIAN_RULES}
>+    "	dh_shlibdeps\n"
>+    "	dh_strip\n" # for reducing size
>+    "	dpkg-gencontrol -p${CPACK_DEBIAN_PACKAGE_NAME}\n"
>+    "	dpkg --build debian/tmp ..\n"
>+    )
>+
>+  foreach(COMPONENT ${CPACK_COMPONENTS_ALL})
>+    set(PATH debian/${COMPONENT})
>+    file(APPEND ${DEBIAN_RULES}
>+      "	dpkg-gencontrol -p${COMPONENT} -P${PATH} -Tdebian/${COMPONENT}.substvars\n"
>+      "	dpkg --build ${PATH} ..\n"
>+      )
>+  endforeach(COMPONENT ${CPACK_COMPONENTS_ALL})
>+
>+  file(APPEND ${DEBIAN_RULES}
>+    "\n"
>+    "clean:\n"
>+    "	rm -f build\n"
>+    "	rm -rf $(BUILDDIR)\n"
>+    "\n"
>+    ".PHONY: binary binary-arch binary-indep clean\n"
>+    )
>+
>+  execute_process(COMMAND chmod +x ${DEBIAN_RULES})
>+
>+  ##############################################################################
>+  # debian/compat
>+  file(WRITE ${DEBIAN_SOURCE_DIR}/debian/compat "7")
>+
>+  ##############################################################################
>+  # debian/source/format
>+  file(WRITE ${DEBIAN_SOURCE_DIR}/debian/source/format "3.0 (quilt)")
>+
>+  ##############################################################################
>+  # debian/changelog
>+  set(DEBIAN_CHANGELOG ${DEBIAN_SOURCE_DIR}/debian/changelog)
>+  execute_process(COMMAND date -R  OUTPUT_VARIABLE DATE_TIME)
>+  file(WRITE ${DEBIAN_CHANGELOG}
>+    "${CPACK_DEBIAN_PACKAGE_NAME} (${RELEASE_PACKAGE_VERSION}) ${RELEASE}; urgency=medium\n\n"
>+    "  * Package built with CMake\n\n"
>+    "${CPACK_DEBIAN_CHANGELOG}"
>+    " -- ${CPACK_PACKAGE_CONTACT}  ${DATE_TIME}"
>+    )
>+
>+  ##############################################################################
>+  # debuild -S
>+  if( DEB_SOURCE_CHANGES )
>+    set(DEBUILD_OPTIONS "-sd")
>+  else()
>+    set(DEBUILD_OPTIONS "-sa")
>+  endif()
>+  set(SOURCE_CHANGES_FILE "${CPACK_DEBIAN_PACKAGE_NAME}_${RELEASE_PACKAGE_VERSION}_source.changes")
>+  set(DEB_SOURCE_CHANGES ${DEB_SOURCE_CHANGES} "${SOURCE_CHANGES_FILE}")
>+  add_custom_command(OUTPUT "${SOURCE_CHANGES_FILE}" COMMAND ${DEBUILD_EXECUTABLE} -S ${DEBUILD_OPTIONS} WORKING_DIRECTORY ${DEBIAN_SOURCE_DIR})
>+endforeach(RELEASE ${CPACK_DEBIAN_DISTRIBUTION_RELEASES})
>+
>+##############################################################################
>+# dput ppa:your-lp-id/ppa <source.changes>
>+add_custom_target(dput ${DPUT_EXECUTABLE} ${DPUT_HOST} ${DEB_SOURCE_CHANGES} DEPENDS ${DEB_SOURCE_CHANGES} WORKING_DIRECTORY ${CMAKE_BINARY_DIR}/Debian)
>diff -urN fparser.orig/modules-cmake/FindGMP.cmake fparser/modules-cmake/FindGMP.cmake
>--- fparser.orig/modules-cmake/FindGMP.cmake	1970-01-01 01:00:00.000000000 +0100
>+++ fparser/modules-cmake/FindGMP.cmake	2014-02-24 15:46:03.947532150 +0100
>@@ -0,0 +1,80 @@
>+# Try to find the GMP libraries
>+# GMP_FOUND - system has GMP lib
>+# GMP_INCLUDE_DIR - the GMP include directory
>+# GMP_LIBRARIES_DIR - Directory where the GMP libraries are located
>+# GMP_LIBRARIES - the GMP libraries
>+# GMP_IN_CGAL_AUXILIARY - TRUE if the GMP found is the one distributed with CGAL in the auxiliary folder
>+
>+# TODO: support MacOSX
>+
>+include(CGAL_FindPackageHandleStandardArgs)
>+include(CGAL_GeneratorSpecificSettings)
>+
>+if(GMP_INCLUDE_DIR)
>+  set(GMP_in_cache TRUE)
>+else()
>+  set(GMP_in_cache FALSE)
>+endif()
>+if( CGAL_AUTO_LINK_GMP )
>+  if(NOT GMP_LIBRARIES_DIR)
>+    set(GMP_in_cache FALSE)
>+  endif()
>+else()
>+  if(NOT GMP_LIBRARIES)
>+    set(GMP_in_cache FALSE)
>+  endif()
>+endif()
>+
>+# Is it already configured?
>+if (GMP_in_cache)
>+   
>+  set(GMP_FOUND TRUE)
>+  
>+else()  
>+
>+  find_path(GMP_INCLUDE_DIR 
>+            NAMES gmp.h 
>+            PATHS ENV GMP_INC_DIR
>+                  ${CMAKE_SOURCE_DIR}/auxiliary/gmp/include
>+  	        DOC "The directory containing the GMP header files"
>+           )
>+
>+  if ( GMP_INCLUDE_DIR STREQUAL "${CMAKE_SOURCE_DIR}/auxiliary/gmp/include" )
>+    cache_set( GMP_IN_CGAL_AUXILIARY TRUE )
>+  endif()
>+  
>+  if ( CGAL_AUTO_LINK_GMP )
>+  
>+    find_path(GMP_LIBRARIES_DIR 
>+              NAMES "gmp-${CGAL_TOOLSET}-mt.lib" "gmp-${CGAL_TOOLSET}-mt-gd.lib"
>+              PATHS ENV GMP_LIB_DIR
>+                    ${CMAKE_SOURCE_DIR}/auxiliary/gmp/lib
>+              DOC "Directory containing the GMP library"
>+             ) 
>+    
>+  else()
>+  
>+    find_library(GMP_LIBRARIES NAMES gmp libgmp-10
>+                 PATHS ENV GMP_LIB_DIR
>+                 ${CMAKE_SOURCE_DIR}/auxiliary/gmp/lib
>+                 DOC "Path to the GMP library"
>+                )
>+                
>+    if ( GMP_LIBRARIES ) 
>+      get_filename_component(GMP_LIBRARIES_DIR ${GMP_LIBRARIES} PATH CACHE )
>+    endif()
>+    
>+  endif()  
>+    
>+  # Attempt to load a user-defined configuration for GMP if couldn't be found
>+  if ( NOT GMP_INCLUDE_DIR OR NOT GMP_LIBRARIES_DIR )
>+    include( GMPConfig OPTIONAL )
>+  endif()
>+  
>+  if(CGAL_AUTO_LINK_GMP)
>+    find_package_handle_standard_args(GMP "DEFAULT_MSG" GMP_LIBRARIES_DIR GMP_INCLUDE_DIR)
>+  else()
>+    find_package_handle_standard_args(GMP "DEFAULT_MSG" GMP_LIBRARIES GMP_INCLUDE_DIR)
>+  endif()
>+  
>+endif()
>diff -urN fparser.orig/modules-cmake/FindGMPXX.cmake fparser/modules-cmake/FindGMPXX.cmake
>--- fparser.orig/modules-cmake/FindGMPXX.cmake	1970-01-01 01:00:00.000000000 +0100
>+++ fparser/modules-cmake/FindGMPXX.cmake	2014-02-24 15:46:03.940532395 +0100
>@@ -0,0 +1,33 @@
>+# Try to find the GMPXX libraries
>+# GMPXX_FOUND - system has GMPXX lib
>+# GMPXX_INCLUDE_DIR - the GMPXX include directory
>+# GMPXX_LIBRARIES - Libraries needed to use GMPXX
>+
>+# TODO: support Windows and MacOSX
>+
>+# GMPXX needs GMP
>+
>+find_package( GMP QUIET )
>+
>+if(GMP_FOUND)
>+
>+  if (GMPXX_INCLUDE_DIR AND GMPXX_LIBRARIES)
>+    # Already in cache, be silent
>+    set(GMPXX_FIND_QUIETLY TRUE)
>+  endif()
>+
>+  find_path(GMPXX_INCLUDE_DIR NAMES gmpxx.h 
>+            PATHS ${GMP_INCLUDE_DIR_SEARCH}
>+            DOC "The directory containing the GMPXX include files"
>+           )
>+
>+  find_library(GMPXX_LIBRARIES NAMES gmpxx
>+               PATHS ${GMP_LIBRARIES_DIR_SEARCH}
>+               DOC "Path to the GMPXX library"
>+               )
>+               
>+  include(CGAL_FindPackageHandleStandardArgs)
>+  
>+  find_package_handle_standard_args(GMPXX "DEFAULT_MSG" GMPXX_LIBRARIES GMPXX_INCLUDE_DIR )
>+
>+endif()
>diff -urN fparser.orig/modules-cmake/FindMPFI.cmake fparser/modules-cmake/FindMPFI.cmake
>--- fparser.orig/modules-cmake/FindMPFI.cmake	1970-01-01 01:00:00.000000000 +0100
>+++ fparser/modules-cmake/FindMPFI.cmake	2014-02-24 15:46:03.924532955 +0100
>@@ -0,0 +1,39 @@
>+find_package( GMP QUIET )
>+
>+if( GMP_FOUND )
>+
>+  if( MPFI_INCLUDE_DIR AND MPFI_LIBRARIES )
>+    set( MPFI_FOUND TRUE )
>+  endif( MPFI_INCLUDE_DIR AND MPFI_LIBRARIES )
>+
>+  find_path(MPFI_INCLUDE_DIR NAMES mpfi.h
>+            PATHS ${GMP_INCLUDE_DIR_SEARCH} ENV MPFI_INC_DIR
>+            DOC "The directory containing the MPFI header files"
>+           )
>+
>+  find_library(MPFI_LIBRARIES NAMES mpfi
>+               PATHS ${GMP_LIBRARIES_DIR_SEARCH} ENV MPFI_LIB_DIR
>+               DOC "Directory containing the MPFI library"
>+               )
>+
>+  if( MPFI_LIBRARIES )
>+    get_filename_component(MPFI_LIBRARIES_DIR ${MPFI_LIBRARIES} PATH CACHE )
>+  endif( MPFI_LIBRARIES )
>+
>+  if( NOT MPFI_INCLUDE_DIR OR NOT MPFI_LIBRARIES_DIR )
>+    include( MPFIConfig OPTIONAL )
>+  endif( NOT MPFI_INCLUDE_DIR OR NOT MPFI_LIBRARIES_DIR )
>+
>+  include(CGAL_FindPackageHandleStandardArgs)
>+
>+  find_package_handle_standard_args(MPFI "DEFAULT_MSG" MPFI_LIBRARIES MPFI_INCLUDE_DIR )
>+
>+else( GMP_FOUND )
>+
>+  message( STATUS "MPFI needs GMP and MPFR" )
>+
>+endif( GMP_FOUND )
>+
>+if( MPFI_FOUND )
>+  set( MPFI_USE_FILE "CGAL_UseMPFI" )
>+endif( MPFI_FOUND )
>diff -urN fparser.orig/modules-cmake/FindMPFR.cmake fparser/modules-cmake/FindMPFR.cmake
>--- fparser.orig/modules-cmake/FindMPFR.cmake	1970-01-01 01:00:00.000000000 +0100
>+++ fparser/modules-cmake/FindMPFR.cmake	2014-02-24 15:46:03.944532255 +0100
>@@ -0,0 +1,81 @@
>+# Try to find the MPFR libraries
>+# MPFR_FOUND - system has MPFR lib
>+# MPFR_INCLUDE_DIR - the MPFR include directory
>+# MPFR_LIBRARIES_DIR - Directory where the MPFR libraries are located
>+# MPFR_LIBRARIES - the MPFR libraries
>+# MPFR_IN_CGAL_AUXILIARY - TRUE if the MPFR found is the one distributed with CGAL in the auxiliary folder
>+
>+# TODO: support MacOSX
>+
>+include(CGAL_FindPackageHandleStandardArgs)
>+include(CGAL_GeneratorSpecificSettings)
>+
>+if(MPFR_INCLUDE_DIR)
>+  set(MPFR_in_cache TRUE)
>+else()
>+  set(MPFR_in_cache FALSE)
>+endif()
>+if( CGAL_AUTO_LINK_MPFR )
>+  if(NOT MPFR_LIBRARIES_DIR)
>+    set(MPFR_in_cache FALSE)
>+  endif()
>+else()
>+  if(NOT MPFR_LIBRARIES)
>+    set(MPFR_in_cache FALSE)
>+  endif()
>+endif()
>+
>+# Is it already configured?
>+if (MPFR_in_cache) 
>+   
>+  set(MPFR_FOUND TRUE)
>+  
>+else()  
>+
>+  find_path(MPFR_INCLUDE_DIR 
>+            NAMES mpfr.h 
>+            PATHS ENV MPFR_INC_DIR
>+                  ${CMAKE_SOURCE_DIR}/auxiliary/gmp/include
>+  	    DOC "The directory containing the MPFR header files"
>+           )
>+
>+  if ( MPFR_INCLUDE_DIR STREQUAL "${CMAKE_SOURCE_DIR}/auxiliary/gmp/include" )
>+    cache_set( MPFR_IN_CGAL_AUXILIARY TRUE )
>+  endif()
>+  
>+  if ( CGAL_AUTO_LINK_MPFR )
>+  
>+    find_path(MPFR_LIBRARIES_DIR 
>+              NAMES "mpfr-${CGAL_TOOLSET}-mt.lib" "mpfr-${CGAL_TOOLSET}-mt-gd.lib"
>+              PATHS ENV MPFR_LIB_DIR
>+                    ${CMAKE_SOURCE_DIR}/auxiliary/gmp/lib
>+              DOC "Directory containing the MPFR library"
>+             ) 
>+    
>+  else()
>+  
>+    find_library(MPFR_LIBRARIES NAMES mpfr libmpfr-4 libmpfr-1
>+                 PATHS ENV MPFR_LIB_DIR
>+                    ${CMAKE_SOURCE_DIR}/auxiliary/gmp/lib
>+                 DOC "Path to the MPFR library"
>+                )
>+                
>+    if ( MPFR_LIBRARIES ) 
>+      get_filename_component(MPFR_LIBRARIES_DIR ${MPFR_LIBRARIES} PATH CACHE )
>+    endif()
>+    
>+  endif()  
>+  
>+  # Attempt to load a user-defined configuration for MPFR if couldn't be found
>+  if ( NOT MPFR_INCLUDE_DIR OR NOT MPFR_LIBRARIES_DIR )
>+    include( MPFRConfig OPTIONAL )
>+  endif()
>+
>+  if(CGAL_AUTO_LINK_MPFR)
>+    find_package_handle_standard_args(MPFR "DEFAULT_MSG" MPFR_LIBRARIES_DIR MPFR_INCLUDE_DIR)
>+  else()
>+    find_package_handle_standard_args(MPFR "DEFAULT_MSG" MPFR_LIBRARIES MPFR_INCLUDE_DIR)
>+  endif()
>+
>+endif()
>+

Actions: View | Diff

Attachments on bug 1069257: 866996 | 866997 | 866998 | 876324