Attachment 926873 Details for Bug 961011 – This is the corrected syntax accepted by the selector parser

This is the corrected syntax accepted by the selector parser

selectors_bnf_trunk.txt (text/plain), 1.97 KB, created by Andrew Stitcher on 2014-08-14 17:59:17 UTC

(hide)

Description:

Filename:

MIME Type:

Creator: Andrew Stitcher

Created: 2014-08-14 17:59:17 UTC

Size: 1.97 KB

patch

obsolete

>SelectExpression ::= OrExpression? // If the overall expression is empty it evaluates to true
>
>// Lexical Elements
>Alpha ::= [a-zA-Z]
>Digit ::= [0-9]
>
>IdentifierInitial ::= Alpha | "_" | "$"
>IdentifierPart ::= IdentifierInitial | Digit | "."
>Identifier ::= IdentifierInitial IdentifierPart*
>Constraint : Identifier NOT IN ("NULL", "TRUE", "FALSE", "NOT", "AND", "OR", "BETWEEN", "LIKE", "IN", "IS", "ESCAPE")  // Note 1
>
>
>LiteralString ::= ("'" [^']* "'")+  // Note 2
>LiteralExactNumeric ::= Digit+
>Exponent ::= ("+"|"-")? LiteralExactNumeric
>LiteralApproxNumeric ::=  Digit "." Digit* ( "E" Exponent )?  |
>                           "." Digit+ ( "E" Exponent )?  |
>                           Digit+ "E" Exponent   // Note 1
>LiteralBool ::= "TRUE" | "FALSE"   // Note 1
>Literal ::= LiteralBool | LiteralString | LiteralApproxNumeric | LiteralExactNumeric
>
>
>EqOps ::= "=" | "<>"
>ComparisonOps ::= EqOps | ">" | ">=" | "<" | "<="
>AddOps ::= "+" | "-"
>MultiplyOps ::= "*" | "/"
>
>// Expression syntax
>OrExpression ::= AndExpression  ( "OR" AndExpression )*
>AndExpression ::= ComparisonExpression ( "AND" ComparisonExpression )*
>ComparisonExpression ::= AddExpression "IS" "NOT"? "NULL" |
>                         AddExpression "NOT"? "LIKE" LiteralString ( "ESCAPE" LiteralString )? | // Note 5
>                         AddExpression "NOT"? "BETWEEN" AddExpression "AND" AddExpression |
>                         AddExpression "NOT"? "IN" "(" PrimaryExpression ("," PrimaryExpression)* ")" |
>                         AddExpression ComparisonOps AddExpression |
>                         "NOT" ComparisonExpression |
>                         AddExpression   // Note 3
>
>
>AddExpression ::= MultiplyExpression (  AddOps MultiplyExpression )*
>MultiplyExpression ::= UnaryArithExpression ( MultiplyOps UnaryArithExpression )*
>UnaryArithExpression ::= AddOps AddExpression |
>                         "(" OrExpression ")" |
>                         PrimaryExpression
>PrimaryExpression ::= Identifier |
>                      Literal

Actions: View

Attachments on bug 961011: 926682 | 926873