Description of problem:

/usr/share/autoconf/autoconf/c.m4 lines 2747-2772 read:

AC_DEFUN([_AC_PROG_CXX_STDCXX_EDITION_TRY],
[AC_LANG_ASSERT([C++])]dnl
[AC_REQUIRE([_AC_CXX_CXX$1_TEST_PROGRAM])]dnl
[AS_IF([test x$ac_prog_cxx_stdcxx = xno],
[AC_MSG_CHECKING([for $CXX option to enable C++$1 features])
AC_CACHE_VAL(ac_cv_prog_cxx_$1,
[ac_cv_prog_cxx_$1=no
ac_save_CXX=$CXX
AC_LANG_CONFTEST([AC_LANG_DEFINES_PROVIDED][$][ac_cxx_conftest_cxx$1_program])
for ac_arg in '' m4_normalize(m4_defn([_AC_CXX_CXX$1_OPTIONS]))
do
  CXX="$ac_save_CXX $ac_arg"
  _AC_COMPILE_IFELSE([], [ac_cv_prog_cxx_cxx$1=$ac_arg])
  test "x$ac_cv_prog_cxx_cxx$1" != "xno" && break
done
rm -f conftest.$ac_ext
CXX=$ac_save_CXX])
AS_IF([test "x$ac_cv_prog_cxx_cxx$1" = xno],
  [AC_MSG_RESULT([unsupported])],
  [AS_IF([test "x$ac_cv_prog_cxx_cxx$1" = x],
    [AC_MSG_RESULT([none needed])],
    [AC_MSG_RESULT([$ac_cv_prog_cxx_cxx$1])
     CXX="$CXX $ac_cv_prog_cxx_cxx$1"])
  ac_cv_prog_cxx_stdcxx=$ac_cv_prog_cxx_cxx$1
  ac_prog_cxx_stdcxx=cxx$1])])
])

The variable $ac_cv_prog_cxx_cxx$1 is misspelled as ac_cv_prog_cxx_$1 on the line 2752 and 2753. Those lines should read:

AC_CACHE_VAL(ac_cv_prog_cxx_cxx$1,
[ac_cv_prog_cxx_cxx$1=no

Because the variable with the correct name is not initialized the test gives the wrong result (which happens e.g. if the generated configure scripts is used on CentOS 7 / RHEL 7).

Version-Release number of selected component (if applicable):

autoconf-2.71-2.fc36.noarch

How reproducible:

Always

Steps to Reproduce:
1. Use AC_PROG_CXX in a configure.ac 
2. Run the generated configure script on Centos 7 or RHEL 7.
3. The configure scripts gives the wrong result for C++ 11 flags.

Actual results:

(when running configure script generated on Fedora 36 on CentOS 7)
checking for g++ option to enable C++11 features... none needed

Expected results:

(when running configure script generated on Fedora 36 on CentOS 7)
checking for g++ option to enable C++11 features... -std=gnu++11

Additional info:

There is a workaround: If you instead of:

AC_PROG_CXX

write:

ac_cv_prog_cxx_cxx11=no
AC_PROG_CXX

in configure.ac, i.e. if you manually initialize the variable to the correct starting value, the test works. But you should not have to do this.